How to detect whether there is a selection in a QML based plugin

• Jan 2, 2013 - 15:47

Î'm trying to get the same effect in 2.0 QML based plugins as we have for the pre 2.x ones in

// Apply the given function to all notes in selection
// or, if nothing is selected, in the entire score
function applyToNotesInSelection(func) {
      if (typeof curScore === 'undefined')
            return;

      var cursor     = new Cursor(curScore);
      cursor.goToSelectionStart();
      var startStaff  = cursor.staff;
      cursor.goToSelectionEnd();
      var endStaff   = cursor.staff;
      var endTick    = cursor.tick() // if no selection, end of score
 
      if (cursor.eos()) { // no selection
            startStaff = 0; // start with 1st staff
            endStaff = curScore.staves; // and end with last
      }

      for (var staff = startStaff; staff < endStaff; ++staff) {
            for (var voice = 0; voice < 4; voice++) {          
                  cursor.goToSelectionStart(); // sets voice to 0
                  cursor.voice = voice; //voice has to be set after goTo
                  cursor.staff = staff;
                  if (cursor.eos())
                          cursor.rewind() // if no selection, beginning of score

                  while (cursor.tick() < endTick) {
                        if (cursor.isChord()) {
                              var chord = cursor.chord();
                              var n     = chord.notes;
                              for (var i = 0; i < n; i++) {
                                    var note   = chord.note(i);
                                    func(note);
                              }
                        }
                        cursor.next();
                  }
            }
      }
}

I think it is very usefull for almost any plugin to work on a selection, if there is one, and on the entire score otherwise.
Any idea how to get this to work?
So far I only know how to process either the entire score or a selection.

Comments

Jojo-Schmitz

• Jan 11, 2013 - 10:46

bump
No idea anybody?
Should this get turned into an enhancement request?

Something like having a read-only property 'bool selection' for curScore which tells whether there is or isn't something selected?

[DELETED] 5

• Feb 7, 2013 - 15:37

It's possible. The function name in the new QML framework are not that user friendly though. Here is a working color note to selection plugin in MuseScore f80dfa796c

import QtQuick 1.0
import MuseScore 1.0
 
MuseScore {
      version:  "1.0"
      description: "This demo plugin colors notes in the selection depending on pitch"
      menuPath: "Plugins.colornotes"
 
      property variant colors : [
               "#e21c48", "#f26622", "#f99d1c",
               "#ffcc33", "#fff32b", "#bcd85f",
               "#62bc47", "#009c95", "#0071bb",
               "#5e50a1", "#8d5ba6", "#cf3e96"
               ]
 
      // Apply the given function to all notes in selection
      // or, if nothing is selected, in the entire score
      function applyToNotesInSelection(func) {
            if (typeof curScore === 'undefined')
                  return;
       
            var cursor     = curScore.newCursor();
            cursor.rewind(1);
            var startStaff  = cursor.staffIdx;
            cursor.rewind(2);
            var endStaff   = cursor.staffIdx;
            var endTick    = cursor.tick // if no selection, end of score
            var fullScore = false;
            if (!cursor.segment) { // no selection
                  fullScore = true;
                  startStaff = 0; // start with 1st staff
                  endStaff = curScore.nstaves; // and end with last
            }
       console.log(startStaff + " - " + endStaff + " - " + endTick)
            for (var staff = startStaff; staff <= endStaff; staff++) {
                  for (var voice = 0; voice < 4; voice++) {          
                        cursor.rewind(1); // sets voice to 0
                        cursor.voice = voice; //voice has to be set after goTo
                        cursor.staffIdx = staff;

                        if (!cursor.segment)
                              cursor.rewind(0) // if no selection, beginning of score

                        while (cursor.segment && (fullScore || cursor.tick < endTick)) {
                              if (cursor.element && cursor.element.type == Element.CHORD) {
                                    var notes = cursor.element.notes;
                                    for (var i = 0; i < notes.length; i++) {
                                          var note = notes[i];
                                          func(note);
                                    }
                              }
                              cursor.next();
                        }
                  }
            }
      }
 
      function colorNote(note) {
            note.color = colors[note.pitch % 12];
      }
 
      onRun: {
            console.log("hello colornotes");
 
            if (typeof curScore === 'undefined')
                  Qt.quit();
 
            applyToNotesInSelection(colorNote)
 
            Qt.quit();
         }
}

Jojo-Schmitz

• Feb 7, 2013 - 17:28

Ah! So testing "if (!cursor.segment)" and using "var endTick = cursor.tick // if no selection, end of score" is the trick here.
I'll have a play with that, thanks.

{Edit 1] Hmm, that colornotes plugin is not part of MuseScore yet, right? Mind to add/update it?

[Edit 2] Well, it does work on a selection, but I can't get it to work with nothing selected, nothing gets colored then

Jojo-Schmitz

• Feb 7, 2013 - 20:32

I can't get your example to work.
Also this
endStaff = curScore.staves; // and end with last
needs to be
endStaff = curScore.nstaves; // and end with last
But that still doesn't make it work, not for the entire score at least, only for a selection.

Problem might be that we don't have a rewind to end of score.

[DELETED] 5

• Feb 7, 2013 - 21:27

gist updated to work on the full score as well.

Jojo-Schmitz

• Feb 7, 2013 - 22:38

Yep, that works, thanks.

Well, mostly. If you first run or agains a selection (which work) and than run it without a selection, it doesn't do anything. Actually it seems to remeber and work on the old selection again, which isn't a visible change, but gets apparent when undoing the previous change.

[DELETED] 5

• Feb 7, 2013 - 23:28

That's probably an inner problem in the way the selection is managed in MuseScore. It seems to remove it from the screen but not internally. It's fixed in 3d55d907e8

Jojo-Schmitz

• Feb 8, 2013 - 07:43

yes, that was my suspicion. Thanks for fixing it!

Now I think it is time to get your improved colornotes into the trunk to replace the current one, wouldn't you agree?

Jojo-Schmitz

• Feb 8, 2013 - 12:58

Part of pull request 204